home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 001 / int13v20.arc / INT13.ASM next >
Assembly Source File  |  1985-12-06  |  16KB  |  466 lines
  1. PAGE 64,132
  2. ;
  3. ;         This program intercepts Int 13H calls and prints
  4. ;         the drive, side, track, sector, # of sectors, operation,
  5. ;         and return code.
  6. ; 
  7. ;--------------------------------------------------------------
  8. DISKSTAT segment at 040h ;segment starts at abs. addr. 0400h
  9.          org 042h
  10. ST0      db ?        ;Disk status area used after 
  11. ST1      db ?        ;  int 13h calls
  12. ST2      db ?
  13. CYLINDER db ?
  14. HEAD     db ?
  15. RECORD   db ?
  16. NUMBER   db ?
  17. DISKSTAT ends
  18. ;--------------------------------------------------------------
  19. ;
  20. cseg    segment 
  21.         org 100h
  22. INT13   proc far
  23.         assume cs:cseg,ds:cseg
  24. ;
  25.         jmp install                    ;install and make routine resident
  26. ;
  27. redef13      label      word
  28. oldint13     dd         0              ;save area for old int13 vector
  29. int13loc     equ        13h*4h         ;vector location for int13h
  30. drive_a      equ         'A'
  31. drive_b      equ         'B'
  32. drive_c      equ         'C'
  33. drive_d      equ         'D'
  34. drive_x      equ         'X'
  35. save_ip      dw         0              ;save area for calling pgm's IP
  36. save_cs      dw         0              ;save area for calling pgm's CS
  37. save_st0     db         ?
  38. save_st1     db         ?
  39. save_st2     db         ?
  40. save_c       db         ?
  41. save_h       db         ?
  42. save_r       db         ?
  43. save_n       db         ?
  44. ;
  45. message      db 0fh        ;   code for compressed printing
  46.              db 'Drv: '
  47. drive        db ?
  48.              db ' Side: '
  49. side1        db ?
  50. side2        db ?
  51.              db '   Tr: '
  52. track1       db ?
  53. track2       db ?
  54.              db ' Sec: '
  55. sector1      db ?
  56. sector2      db ?
  57.              db '  # secs: '
  58. sec_cnt1     db ?
  59. sec_cnt2     db ?
  60.              db ' Op: '
  61. op_1         db ?
  62. op_2         db ?
  63.              db '   Retcd: '
  64. status1      db ?
  65. status2      db ?
  66.              db '  Addr: '
  67. cs_1         db ?
  68. cs_2         db ?
  69. cs_3         db ?
  70. cs_4         db ?
  71.              db ':'
  72. ip_1         db ?
  73. ip_2         db ?
  74. ip_3         db ?
  75. ip_4         db ?
  76.              db '  '     ;2 spaces
  77.              db ' ST0: '
  78. sto0_1       db ?
  79. sto0_2       db ?
  80.              db ' ST1: '
  81. sto1_1       db ?
  82. sto1_2       db ?
  83.              db ' ST2: '
  84. sto2_1       db ?
  85. sto2_2       db ?
  86.              db '  '     ;2spaces
  87.              db ' C: '
  88. c_1          db ?
  89. c_2          db ?
  90.              db ' H: '
  91. h_1          db ?
  92. h_2          db ?
  93.              db ' R: '
  94. r_1          db ?
  95. r_2          db ?
  96.              db ' N: '
  97. n_1          db ?
  98. n_2          db ?
  99.              db 0ah,0dh
  100. ;------------------------------
  101. unin_msg     db 'INT13 no longer active.......$'
  102. inst_msg     db 'INT13 is now installed.......$'
  103. ;
  104. newint13:
  105.         sti
  106.         push ax
  107.         push bp
  108.         mov bp,sp                      
  109.         mov ax,[bp+4]                  ;Retrieve return IP value 
  110.         mov cs:save_ip,ax              ;    from stack.
  111.         mov ax,[bp+6]                  ;Retrieve return CS value
  112.         mov cs:save_cs,ax              ;    from stack.
  113.         pop bp                         ;Save anything which will be
  114.         pop ax                         ;    be changed during
  115.         pushf                          ;    processing.
  116.         push di
  117.         push si
  118.         push ds
  119.         push es
  120.         push bx
  121.         push cx
  122.         push dx
  123.         push ax
  124.         mov ax,cs
  125.         mov ds,ax
  126. ;---------------DRIVE------------------
  127.         cmp dl,00h                     ;Drive A? (dl=00)
  128.         jne chk1                       ; Note: processing is in place for
  129.         mov drive,drive_a              ;    logging disk activity on all
  130.         jmp drv_exit                   ;    drives, if desired.  See below
  131. chk1:   cmp dl,01h                     ;Drive B?
  132.         jne chk2
  133.         mov drive,drive_b
  134.         jmp drv_exit
  135. chk2:   cmp dl,02h                     ;Drive C?
  136.         jne chk3
  137.         mov drive,drive_c
  138.         jmp drv_exit
  139. chk3:   cmp dl,03h
  140.         jne chkx
  141.         mov drive,drive_d
  142.         jmp drv_exit
  143. chkx:   mov drive,drive_x
  144. drv_exit:
  145. ;---------------SIDE  (DH) ------------
  146.         mov ah,dh                      ;record side being requested-left digit
  147.         call leftdig                   ;convert to ASCII code for printing
  148.         mov cs:side1,ah                ;move code to message area
  149.         mov ah,dh                      ;same for right digit
  150.         call rightdig
  151.         mov cs:side2,ah
  152. ;---------------TRACK NO. (CH)----------
  153.         mov ah,ch
  154.         call leftdig
  155.         mov cs:track1,ah
  156.         mov ah,ch
  157.         call rightdig
  158.         mov cs:track2,ah
  159. ;----------------------------------------
  160. ;
  161. ;----------------SECTOR NO. (CL)---------
  162.         mov ah,cl
  163.         call leftdig
  164.         mov cs:sector1,ah
  165.         mov ah,cl
  166.         call rightdig
  167.         mov cs:sector2,ah
  168. ;------------------------------------------
  169. ;
  170. ;----------------NO. OF SECTORS (AL)-------
  171. ;
  172.         pop ax      ;recall ax
  173.         push ax     ;save it again
  174.         mov ah,al
  175.         call leftdig
  176.         mov cs:sec_cnt1,ah
  177.         pop ax
  178.         push ax
  179.         mov ah,al
  180.         call rightdig
  181.         mov cs:sec_cnt2,ah
  182. ;--------------------------------------------------
  183. ;
  184. ;--------------OPERATION TYPE (AH)-----------------
  185. ; 00:reset 01:read status 02:read sectors 03:write sec. 04:verify 05:format
  186. ;
  187.  
  188.         pop ax      ;recall ax
  189.         push ax     ;save it again
  190.         call leftdig
  191.         mov cs:op_1,ah
  192.         pop ax
  193.         push ax
  194.         call rightdig
  195.         mov cs:op_2,ah
  196. ;-------------- RETURN ADDRESS CS:IP -------------------
  197. ;
  198.         mov ax,cs:save_ip
  199.         call leftdig
  200.         mov cs:ip_1,ah
  201.         mov ax,cs:save_ip
  202.         call rightdig
  203.         mov cs:ip_2,ah
  204.         mov ax,cs:save_ip
  205.         xchg ah,al
  206.         call leftdig
  207.         mov cs:ip_3,ah
  208.         mov ax,cs:save_ip
  209.         xchg ah,al
  210.         call rightdig
  211.         mov cs:ip_4,ah
  212. ;
  213.         mov ax,cs:save_cs
  214.         call leftdig
  215.         mov cs:cs_1,ah
  216.         mov ax,cs:save_cs
  217.         call rightdig
  218.         mov cs:cs_2,ah
  219.         mov ax,cs:save_cs
  220.         xchg ah,al
  221.         call leftdig
  222.         mov cs:cs_3,ah
  223.         mov ax,cs:save_cs
  224.         xchg ah,al
  225.         call rightdig
  226.         mov cs:cs_4,ah
  227. ;--------------------------------
  228.              pop ax                    ;Restore the things which were
  229.              pop dx                    ;    saved
  230.              pop cx
  231.              pop bx
  232.              pop es
  233.              pop ds
  234.              pop si
  235.              pop di
  236.              popf
  237. ;--------------------
  238.              pushf           ; Put flags, CS and IP onto stack for return to
  239.              push cs         ;  routine below after standard int 13h processing
  240.              call intcall    ; IP will point to next instruction
  241. ;
  242. ;---------------------------Report status of int 13h call----------
  243. ;
  244.              pushf
  245.              push bx
  246.              push ax                   ;Save it again
  247.              call leftdig
  248.              mov cs:status1,ah
  249.              pop ax
  250.              push ax
  251.              call rightdig
  252.              mov cs:status2,ah
  253. ;
  254. ;retrieve the status codes from 0442-0448h
  255. ;
  256.              push ds
  257.              assume ds:diskstat
  258.              mov ax,diskstat
  259.              mov ds,ax
  260.              mov ah,st0
  261.              mov cs:save_st0,ah
  262.              mov ah,st1
  263.              mov cs:save_st1,ah
  264.              mov ah,st2
  265.              mov cs:save_st2,ah
  266.              mov ah,cylinder
  267.              mov cs:save_c,ah
  268.              mov ah,head
  269.              mov cs:save_h,ah
  270.              mov ah,record
  271.              mov cs:save_r,ah
  272.              mov ah,number
  273.              mov cs:save_n,ah
  274.              pop ds
  275.              assume ds:cseg
  276. ;--------------
  277.              mov ah,cs:save_st0
  278.              call leftdig
  279.              mov cs:sto0_1,ah
  280.              mov ah,cs:save_st0
  281.              call rightdig
  282.              mov cs:sto0_2,ah
  283.                 mov ah,cs:save_st1
  284.                 call leftdig
  285.                 mov cs:sto1_1,ah
  286.                 mov ah,cs:save_st1
  287.                 call rightdig
  288.                 mov cs:sto1_2,ah
  289.                    mov ah,cs:save_st2
  290.                    call leftdig
  291.                    mov cs:sto2_1,ah
  292.                    mov ah,cs:save_st2
  293.                    call rightdig
  294.                    mov cs:sto2_2,ah
  295.              mov ah,cs:save_c
  296.              call leftdig
  297.              mov cs:c_1,ah
  298.              mov ah,cs:save_c
  299.              call rightdig
  300.              mov cs:c_2,ah
  301.                  mov ah,cs:save_h
  302.                  call leftdig
  303.                  mov cs:h_1,ah
  304.                  mov ah,cs:save_h
  305.                  call rightdig
  306.                  mov cs:h_2,ah
  307.                      mov ah,cs:save_r
  308.                      call leftdig
  309.                      mov cs:r_1,ah
  310.                      mov ah,cs:save_r
  311.                      call rightdig
  312.                      mov cs:r_2,ah
  313.                          mov ah,cs:save_n
  314.                          call leftdig
  315.                          mov cs:n_1,ah
  316.                          mov ah,cs:save_n
  317.                          call rightdig
  318.                          mov cs:n_2,ah
  319.              pop ax
  320.              pop bx
  321. ;------------  PRINT THE MESSAGE --------------------------
  322.              cmp dl,00h  ;******** REMOVE THESE TWO LINES IF YOU WISH
  323.              jne goback  ;********   ALL DISK ACTIVITY TO BE LOGGED
  324.              push ax
  325.              push cx
  326.              push dx
  327.              push si
  328.              mov cx,87h                ; Length of message
  329.              mov si,offset message
  330.              xor dx,dx
  331. prnloop:     mov ah,00h
  332.              mov al,cs:[si]  
  333.              int 17h
  334.              inc si
  335.              loop prnloop
  336.              pop si
  337.              pop dx
  338.              pop cx
  339.              pop ax
  340. goback:      popf
  341. ;-------------------------------------------------------
  342.              ret  2          ; Go back to calling program.
  343.                              ; Note:"iret" is not used because the flags
  344.                              ;   would be popped (and we wish to pass back
  345.                              ;   the changed set of flags).  The "2" ensures
  346.                              ;   that the stack is restored by incrementing
  347.                              ;   the stack pointer by two extra bytes.
  348. ;-----------------------
  349. intcall      PROC near     ; get set to go to standard int 13h routine
  350.              pushf
  351.              push cs:[redef13 + 2]     ; "cs" of int 13h routine
  352.              push cs:[redef13]         ; "ip" of int 13h routine
  353.              iret                      ; Branch to normal int13h code in ROM
  354. intcall      endp 
  355. ;--------------------------
  356. ;   Routine to convert high-order digit in AH to an ASCII character
  357. ;
  358. leftdig      PROC
  359.              and ah,11110000b ; Mask right 4 bits
  360.              shr ah,1         ; Move high-order digit to low-order pos.
  361.              shr ah,1
  362.              shr ah,1
  363.              shr ah,1
  364.              cmp ah,0ah       ; Check for value 0 through 9
  365.              jnb b37          ; If value hex A through F, jump 
  366.              add ah,30h       ; Add 30h to make ASCII character
  367.              jmp b2
  368.        b37:  add ah,37h       ; If hex A-F, add 37h to make ASCII character
  369.         b2:  ret
  370. leftdig      endp
  371. ;-----------------------
  372. ;   Routine to convert low-order digit in AH to an ASCII character
  373. ;
  374. rightdig     PROC near
  375.              and ah,00001111b ; mask left 4 bits
  376.              cmp ah,0ah
  377.              jnb a37
  378.              add ah,30h
  379.              jmp a1
  380.        a37:  add ah,37h
  381.         a1:  ret
  382. rightdig     endp
  383. ;-----------------------
  384. install:
  385.  
  386. ;     First, determine if INT13 has already been installed...
  387.              push ds                   ;Save DS
  388.              mov ax,0000h
  389.              mov ds,ax                 ;Need 0 in DS
  390.              mov di,int13loc           ;Move 4C to DI
  391.              mov bx,[di]               ;"IP" of current Int 13 routine
  392.              mov ax,[di+2]             ;"CS" of current Int 13 routine
  393.              mov ds,ax                 ;Establish new DS register value
  394.              mov ch,[bx-1]             ;Get byte just before entry point
  395.              pop ds                    ;Restore DS value at entry
  396.              cmp ch,024h               ;Look for a "$"
  397.              je un_inst                ;If =, then Int13 is already active
  398. ;     Proceed with installation 
  399.              mov ax,0
  400.              mov es,ax
  401.              mov di,int13loc           ;Save old 
  402.              mov ax,es:[di]            ;   interrupt 13h
  403.              mov bx,es:[di+2]          ;   vector
  404.              mov si,offset oldint13    ;     "
  405.              mov [si],ax               ;     "
  406.              mov [si+2],bx             ;     "
  407.              mov ax,0                  
  408.              mov es,ax
  409.              mov bx,ds
  410.              cli                       ;Turn off interrupts
  411.              mov di,int13loc           ;Change int13h ....
  412.              mov ax,offset newint13    ;   vector to...
  413.              mov es:[di],ax            ;   point to...
  414.              mov es:[di+2],bx          ;   this program.
  415.              sti                       ;Turn interrupts back on
  416.              mov dx,offset inst_msg
  417.              mov ah,09h                ;Print string function
  418.              int 21h                   ;Print "install" message
  419. ;
  420. ;---Check if compressed printing is to be disabled ("8" in parameter string)
  421. ;       Note: parameter string begins at offset 81h into COM file header,
  422. ;             and offset 80h contains length of parameter string.
  423. ;
  424.              mov ax,ds                 ;Make sure ES is the same
  425.              mov es,ax                 ;   as DS
  426.              cmp byte ptr es:[80h],00h ;Length of parm. string
  427.              je no_chng                ;If zero, no change
  428.              mov di,081h               ;Start of parm. string
  429.              mov al,038h               ;38h = "8"
  430.              xor ch,ch                 ;Zero high-order byte
  431.              mov cl,es:[80h]           ;Length of parm. string
  432.              cld                       ;Clear direction flag (forward)
  433.              repne scasb               ;Scan ES:DI 'til match with AL,or CX=0
  434.              jne no_chng               ;No match means "8" not in parm. strng
  435.              mov message,00h           ;"8" found, so zero out compress char.
  436. ;----------------------------------------------------------------------------
  437. no_chng:     mov dx,offset install     ;Address of end of resident routine
  438.              int 27h                   ;Terminate and stay resident
  439. ;
  440. ;----------------------------------------------------------------------------
  441. ;
  442. un_inst:     push ds                   ;Save DS again
  443.              mov ds,ax                 ;AX has CS value of current int 13
  444.              mov si,bx                 ;BX has entry point of current int 13
  445.              sub bx,0d2h               ;Backup D2 bytes to find "old" int 13
  446.              mov si,bx                 ;Establish "source" string start point
  447.              mov ax,0h
  448.              mov es,ax                 ;Zero out ES register for move
  449.              mov di,int13loc           ;Establish "destination" (004Ch)
  450.              mov cx,04h                ;4 bytes to move
  451.              cld                       ;Set forward direction for move
  452.              rep movsb                 ;Move from DS:SI to ES:DI until CX=0
  453. ;
  454. ;At this point, the int 13h vector at 0000:004C has been restored to
  455. ;       the value it had when INT13 was previously invoked.
  456. ;
  457.              pop ds                    ;Restore entry DS value
  458.              mov dx,offset unin_msg    ;Location of "un-install" message
  459.              mov ah,09h                ;Prepare for printing
  460.              int 21h                   ;Print the message
  461.              int 20h                   ;Terminate
  462. INT13        endp
  463. ;----------------------------------------------------------------------------
  464. cseg         ends
  465. end          INT13
  466.